Started a Cobor Virtual Machine implementation for running the code.
This commit is contained in:
douwe
176
cobor_vm_extension/godot-cpp/cmake/GodotCPPModule.cmake
Normal file
176
cobor_vm_extension/godot-cpp/cmake/GodotCPPModule.cmake
Normal file
@@ -0,0 +1,176 @@
|
||||
#[=======================================================================[.rst:
|
||||
GodotCPPModule.cmake
|
||||
---------------------
|
||||
|
||||
This file contains functions and tests which may be needed by consumers.
|
||||
|
||||
* Generate Trimmed API
|
||||
* Generate File List
|
||||
* Generate Bindings
|
||||
|
||||
If you want to use these functions in your project extend the CMAKE_MODULE_PATH
|
||||
by adding these two lines into your CMakeLists.txt after the inclusion
|
||||
godot-cpp
|
||||
|
||||
.. highlight:: cmake
|
||||
|
||||
list(APPEND CMAKE_MODULE_PATH "${godot-cpp_SOURCE_DIR}/cmake")
|
||||
include( GodotCPPModule )
|
||||
|
||||
]=======================================================================]
|
||||
find_package(Python3 3.4 REQUIRED) # pathlib should be present
|
||||
|
||||
#[[ Generate Trimmed API
|
||||
|
||||
The build_profile.py has a __main__ and is used as a tool
|
||||
Its usage is listed as:
|
||||
$ python build_profile.py BUILD_PROFILE INPUT_JSON [OUTPUT_JSON]
|
||||
]]
|
||||
function(build_profile_generate_trimmed_api BUILD_PROFILE INPUT_JSON OUTPUT_JSON)
|
||||
execute_process(
|
||||
COMMAND
|
||||
"${Python3_EXECUTABLE}" "${godot-cpp_SOURCE_DIR}/build_profile.py" "${BUILD_PROFILE}" "${INPUT_JSON}"
|
||||
"${OUTPUT_JSON}"
|
||||
WORKING_DIRECTORY ${godot-cpp_SOURCE_DIR}
|
||||
)
|
||||
endfunction()
|
||||
|
||||
#[[ Generate File List
|
||||
|
||||
Use the binding_generator.py Python script to determine the list of files that
|
||||
will be passed to the code generator using extension_api.json.
|
||||
NOTE: This happens for every configure.]]
|
||||
function(binding_generator_get_file_list OUT_VAR_NAME API_FILEPATH OUTPUT_DIR)
|
||||
# This code snippet will be squashed into a single line
|
||||
# The two strings make this a list, in CMake lists are semicolon delimited strings.
|
||||
set(PYTHON_SCRIPT
|
||||
"from binding_generator import print_file_list"
|
||||
"print_file_list( api_filepath='${API_FILEPATH}',
|
||||
output_dir='${OUTPUT_DIR}',
|
||||
headers=True,
|
||||
sources=True)"
|
||||
)
|
||||
message(DEBUG "Python:\n${PYTHON_SCRIPT}")
|
||||
|
||||
# Strip newlines and whitespace to make it a one-liner.
|
||||
string(REGEX REPLACE "\n *" " " PYTHON_SCRIPT "${PYTHON_SCRIPT}")
|
||||
|
||||
execute_process(
|
||||
COMMAND "${Python3_EXECUTABLE}" "-c" "${PYTHON_SCRIPT}"
|
||||
WORKING_DIRECTORY "${godot-cpp_SOURCE_DIR}"
|
||||
OUTPUT_VARIABLE GENERATED_FILES_LIST
|
||||
OUTPUT_STRIP_TRAILING_WHITESPACE
|
||||
)
|
||||
|
||||
# Debug output
|
||||
message(DEBUG "FileList-Begin")
|
||||
foreach(PATH ${GENERATED_FILES_LIST})
|
||||
message(DEBUG ${PATH})
|
||||
endforeach()
|
||||
|
||||
# Error out if the file list generator returned no files.
|
||||
list(LENGTH GENERATED_FILES_LIST LIST_LENGTH)
|
||||
if(NOT LIST_LENGTH GREATER 0)
|
||||
message(FATAL_ERROR "File List Generation Failed")
|
||||
endif()
|
||||
message(STATUS "There are ${LIST_LENGTH} Files to generate")
|
||||
|
||||
set(${OUT_VAR_NAME} ${GENERATED_FILES_LIST} PARENT_SCOPE)
|
||||
endfunction()
|
||||
|
||||
#[[ Generate Bindings
|
||||
|
||||
Using the generated file list, use the binding_generator.py to generate the
|
||||
godot-cpp bindings. This will run at build time only if there are files
|
||||
missing. ]]
|
||||
function(
|
||||
binding_generator_generate_bindings
|
||||
API_FILE
|
||||
USE_TEMPLATE_GET_NODE,
|
||||
BITS,
|
||||
PRECISION,
|
||||
OUTPUT_DIR
|
||||
)
|
||||
# This code snippet will be squashed into a single line
|
||||
set(PYTHON_SCRIPT
|
||||
"from binding_generator import generate_bindings"
|
||||
"generate_bindings(
|
||||
api_filepath='${API_FILE}',
|
||||
use_template_get_node='${USE_TEMPLATE_GET_NODE}',
|
||||
bits='${BITS}',
|
||||
precision='${PRECISION}',
|
||||
output_dir='${OUTPUT_DIR}')"
|
||||
)
|
||||
|
||||
message(DEBUG "Python:\n${PYTHON_SCRIPT}")
|
||||
|
||||
# Strip newlines and whitespace to make it a one-liner.
|
||||
string(REGEX REPLACE "\n *" " " PYTHON_SCRIPT "${PYTHON_SCRIPT}")
|
||||
|
||||
add_custom_command(
|
||||
OUTPUT ${GENERATED_FILES_LIST}
|
||||
COMMAND "${Python3_EXECUTABLE}" "-c" "${PYTHON_SCRIPT}"
|
||||
VERBATIM
|
||||
WORKING_DIRECTORY ${godot-cpp_SOURCE_DIR}
|
||||
MAIN_DEPENDENCY ${GODOTCPP_GDEXTENSION_API_FILE}
|
||||
DEPENDS ${godot-cpp_SOURCE_DIR}/binding_generator.py
|
||||
COMMENT "Generating bindings"
|
||||
)
|
||||
add_custom_target(generate_bindings DEPENDS ${GENERATED_FILES_LIST})
|
||||
set_target_properties(generate_bindings PROPERTIES FOLDER "godot-cpp")
|
||||
endfunction()
|
||||
|
||||
#[[ Generate doc_data.cpp
|
||||
The documentation displayed in the Godot editor is compiled into the extension.
|
||||
It takes a list of XML source files, and transforms them into a cpp file that
|
||||
is added to the sources list.]]
|
||||
function(generate_doc_source OUTPUT_PATH SOURCES)
|
||||
# Transform SOURCES CMake LIST
|
||||
# quote each path with ''
|
||||
# join with , to transform into a python list minus the surrounding []
|
||||
set(PYTHON_LIST "${SOURCES}")
|
||||
list(TRANSFORM PYTHON_LIST REPLACE "(.*\.xml)" "'\\1'")
|
||||
list(JOIN PYTHON_LIST "," PYTHON_LIST)
|
||||
|
||||
get_filename_component(OUTPUT_DIR "${OUTPUT_PATH}" DIRECTORY)
|
||||
file(MAKE_DIRECTORY ${OUTPUT_DIR})
|
||||
|
||||
# Python one-liner to run our command
|
||||
# lists in CMake are just strings delimited by ';', so this works.
|
||||
set(PYTHON_SCRIPT
|
||||
"from doc_source_generator import generate_doc_source"
|
||||
"generate_doc_source( '${OUTPUT_PATH}', [${PYTHON_LIST}] )"
|
||||
)
|
||||
|
||||
add_custom_command(
|
||||
OUTPUT "${OUTPUT_PATH}"
|
||||
COMMAND "${Python3_EXECUTABLE}" "-c" "${PYTHON_SCRIPT}"
|
||||
VERBATIM
|
||||
WORKING_DIRECTORY "${godot-cpp_SOURCE_DIR}"
|
||||
DEPENDS #
|
||||
"${godot-cpp_SOURCE_DIR}/doc_source_generator.py"
|
||||
"${SOURCES}"
|
||||
COMMENT "Generating: ${OUTPUT_PATH}"
|
||||
)
|
||||
add_custom_target(generate_doc_source DEPENDS "${OUTPUT_PATH}")
|
||||
set_target_properties(generate_doc_source PROPERTIES FOLDER "godot-cpp")
|
||||
endfunction()
|
||||
|
||||
#[[ target_doc_sources
|
||||
A simpler interface to add xml files as doc source to a output target.
|
||||
TARGET: The gdexension library target
|
||||
SOURCES: a list of xml files to use for source generation and inclusion.]]
|
||||
function(target_doc_sources TARGET SOURCES)
|
||||
# set the generated file name
|
||||
set(DOC_SOURCE_FILE "${CMAKE_CURRENT_BINARY_DIR}/gen/doc_source.cpp")
|
||||
|
||||
# Create the file generation target, this won't be triggered unless a target
|
||||
# that depends on DOC_SOURCE_FILE is built
|
||||
generate_doc_source( "${DOC_SOURCE_FILE}" ${SOURCES} )
|
||||
|
||||
# Add DOC_SOURCE_FILE as a dependency to TARGET
|
||||
target_sources(${TARGET} PRIVATE "${DOC_SOURCE_FILE}")
|
||||
|
||||
# Without adding this dependency to the doc_source_generator, XCode will complain.
|
||||
add_dependencies(${TARGET} generate_doc_source)
|
||||
endfunction()
|
||||
49
cobor_vm_extension/godot-cpp/cmake/android.cmake
Normal file
49
cobor_vm_extension/godot-cpp/cmake/android.cmake
Normal file
@@ -0,0 +1,49 @@
|
||||
#[=======================================================================[.rst:
|
||||
Android
|
||||
-------
|
||||
|
||||
This file contains functions for options and configuration for targeting the
|
||||
Android platform
|
||||
|
||||
Configuration of the Android toolchain is done using toolchain files,
|
||||
CMakePresets, or variables on the command line.
|
||||
|
||||
The `Android SDK`_ provides toolchain files to help with configuration.
|
||||
|
||||
CMake has its own `built-in support`_ for cross compiling to the
|
||||
Android platforms.
|
||||
|
||||
.. warning::
|
||||
|
||||
Android does not support or test the CMake built-in workflow, recommend
|
||||
using their toolchain file.
|
||||
|
||||
.. _Android SDK:https://developer.android.com/ndk/guides/cmake
|
||||
|
||||
.. _built-in support:https://cmake.org/cmake/help/latest/manual/cmake-toolchains.7.html#cross-compiling-for-android
|
||||
|
||||
There is further information and examples in the doc/cmake.rst file.
|
||||
|
||||
]=======================================================================]
|
||||
|
||||
#[============================[ Android Options ]============================]
|
||||
function(android_options)
|
||||
#[[ Options from SCons
|
||||
|
||||
The options below are managed by CMake toolchain files, doc.cmake.rst has
|
||||
more information
|
||||
|
||||
android_api_level : Target Android API level.
|
||||
Default = 21
|
||||
|
||||
ANDROID_HOME : Path to your Android SDK installation.
|
||||
Default = os.environ.get("ANDROID_HOME", os.environ.get("ANDROID_SDK_ROOT")
|
||||
]]
|
||||
endfunction()
|
||||
|
||||
#[===========================[ Target Generation ]===========================]
|
||||
function(android_generate)
|
||||
target_compile_definitions(godot-cpp PUBLIC ANDROID_ENABLED UNIX_ENABLED)
|
||||
|
||||
common_compiler_flags()
|
||||
endfunction()
|
||||
192
cobor_vm_extension/godot-cpp/cmake/common_compiler_flags.cmake
Normal file
192
cobor_vm_extension/godot-cpp/cmake/common_compiler_flags.cmake
Normal file
@@ -0,0 +1,192 @@
|
||||
#[=======================================================================[.rst:
|
||||
Common Compiler Flags
|
||||
---------------------
|
||||
|
||||
This file contains host platform toolchain and target platform agnostic
|
||||
configuration. It includes flags like optimization levels, warnings, and
|
||||
features. For target platform specific flags look to each of the
|
||||
``cmake/<platform>.cmake`` files.
|
||||
|
||||
The default compile and link options CMake adds can be found in the
|
||||
platform modules_. When a project is created it initializes its variables from
|
||||
the ``CMAKE_*`` values. The cleanest way I have found to alter these defaults
|
||||
is the use of the ``CMAKE_PROJECT_<PROJECT-NAME>_INCLUDE`` as demonstrated by
|
||||
the emsdkHack.cmake to overcome the limitation on shared library creation.
|
||||
|
||||
So far the emsdkHack is the only modification to the defaults we have made.
|
||||
|
||||
.. _modules: https://github.com/Kitware/CMake/blob/master/Modules/Platform/
|
||||
|
||||
]=======================================================================]
|
||||
|
||||
#[[ Compiler Configuration, not to be confused with build targets ]]
|
||||
set(DEBUG_SYMBOLS "$<OR:$<CONFIG:Debug>,$<CONFIG:RelWithDebInfo>>")
|
||||
|
||||
#[[ Compiler Identification ]]
|
||||
set(IS_CLANG "$<CXX_COMPILER_ID:Clang>")
|
||||
set(IS_APPLECLANG "$<CXX_COMPILER_ID:AppleClang>")
|
||||
set(IS_GNU "$<CXX_COMPILER_ID:GNU>")
|
||||
set(IS_MSVC "$<CXX_COMPILER_ID:MSVC>")
|
||||
set(NOT_MSVC "$<NOT:$<CXX_COMPILER_ID:MSVC>>")
|
||||
|
||||
set(LT_V8 "$<VERSION_LESS:$<CXX_COMPILER_VERSION>,8>")
|
||||
set(GE_V9 "$<VERSION_GREATER_EQUAL:$<CXX_COMPILER_VERSION>,9>")
|
||||
set(GT_V11 "$<VERSION_GREATER_EQUAL:$<CXX_COMPILER_VERSION>,11>")
|
||||
set(LT_V11 "$<VERSION_LESS:$<CXX_COMPILER_VERSION>,11>")
|
||||
set(GE_V12 "$<VERSION_GREATER_EQUAL:$<CXX_COMPILER_VERSION>,12>")
|
||||
|
||||
#[===========================[ compiler_detection ]===========================]
|
||||
#[[ Check for clang-cl with MSVC frontend
|
||||
The compiler is tested and set when the project command is called.
|
||||
The variable CXX_COMPILER_FRONTEND_VARIANT was introduced in 3.14
|
||||
The generator expression $<CXX_COMPILER_FRONTEND_VARIANT> wasn't introduced
|
||||
until CMake 3.30 so we can't use it yet.
|
||||
|
||||
So to support clang downloaded from llvm.org which uses the MSVC frontend
|
||||
by default, we need to test for it. ]]
|
||||
function(compiler_detection)
|
||||
if(${CMAKE_CXX_COMPILER_ID} STREQUAL Clang)
|
||||
if(${CMAKE_CXX_COMPILER_FRONTEND_VARIANT} STREQUAL MSVC)
|
||||
message("Using clang-cl")
|
||||
set(IS_CLANG "0" PARENT_SCOPE)
|
||||
set(IS_MSVC "1" PARENT_SCOPE)
|
||||
set(NOT_MSVC "0" PARENT_SCOPE)
|
||||
endif()
|
||||
endif()
|
||||
endfunction()
|
||||
|
||||
#[=========================[ common_compiler_flags ]=========================]
|
||||
#[[ This function assumes it is being called from within one of the platform
|
||||
generate functions, with all the variables from lower scopes defined. ]]
|
||||
function(common_compiler_flags)
|
||||
# gersemi: off
|
||||
# These compiler options reflect what is in godot/SConstruct.
|
||||
target_compile_options(
|
||||
godot-cpp
|
||||
# The public flag tells CMake that the following options are transient,
|
||||
# and will propagate to consumers.
|
||||
PUBLIC
|
||||
# Disable exception handling. Godot doesn't use exceptions anywhere, and this
|
||||
# saves around 20% of binary size and very significant build time.
|
||||
$<${DISABLE_EXCEPTIONS}:$<${NOT_MSVC}:-fno-exceptions>>
|
||||
|
||||
# Enabling Debug Symbols
|
||||
$<${DEBUG_SYMBOLS}:
|
||||
# Adding dwarf-4 explicitly makes stacktraces work with clang builds,
|
||||
# otherwise addr2line doesn't understand them.
|
||||
$<${NOT_MSVC}:
|
||||
-gdwarf-4
|
||||
$<IF:${IS_DEV_BUILD},-g3,-g2>
|
||||
>
|
||||
>
|
||||
|
||||
$<${IS_DEV_BUILD}:$<${NOT_MSVC}:-fno-omit-frame-pointer -O0>>
|
||||
|
||||
$<${HOT_RELOAD}:$<${IS_GNU}:-fno-gnu-unique>>
|
||||
|
||||
# MSVC only
|
||||
$<${IS_MSVC}:
|
||||
# /MP isn't valid for clang-cl with msvc frontend
|
||||
$<$<CXX_COMPILER_ID:MSVC>:/MP${PROC_N}>
|
||||
|
||||
# Interpret source files as utf-8
|
||||
/utf-8
|
||||
>
|
||||
|
||||
# Warnings below, these do not need to propagate to consumers.
|
||||
PRIVATE
|
||||
$<${IS_MSVC}:
|
||||
/W4 # Warning level 4 (informational) warnings that aren't off by default.
|
||||
|
||||
# Disable warnings which we don't plan to fix.
|
||||
/wd4100 # C4100 (unreferenced formal parameter): Doesn't play nice with polymorphism.
|
||||
/wd4127 # C4127 (conditional expression is constant)
|
||||
/wd4201 # C4201 (non-standard nameless struct/union): Only relevant for C89.
|
||||
/wd4244 # C4244 C4245 C4267 (narrowing conversions): Unavoidable at this scale.
|
||||
/wd4245
|
||||
/wd4267
|
||||
/wd4305 # C4305 (truncation): double to float or real_t, too hard to avoid.
|
||||
/wd4514 # C4514 (unreferenced inline function has been removed)
|
||||
/wd4714 # C4714 (function marked as __forceinline not inlined)
|
||||
/wd4820 # C4820 (padding added after construct)
|
||||
>
|
||||
|
||||
# Clang and GNU common options
|
||||
$<$<OR:${IS_CLANG},${IS_GNU}>:
|
||||
-Wall
|
||||
-Wctor-dtor-privacy
|
||||
-Wextra
|
||||
-Wno-unused-parameter
|
||||
-Wnon-virtual-dtor
|
||||
-Wwrite-strings
|
||||
>
|
||||
|
||||
# Clang only
|
||||
$<${IS_CLANG}:
|
||||
-Wimplicit-fallthrough
|
||||
-Wno-ordered-compare-function-pointers
|
||||
>
|
||||
|
||||
# GNU only
|
||||
$<${IS_GNU}:
|
||||
-Walloc-zero
|
||||
-Wduplicated-branches
|
||||
-Wduplicated-cond
|
||||
-Wno-misleading-indentation
|
||||
-Wplacement-new=1
|
||||
-Wshadow-local
|
||||
-Wstringop-overflow=4
|
||||
|
||||
# Bogus warning fixed in 8+.
|
||||
$<${LT_V8}:-Wno-strict-overflow>
|
||||
|
||||
$<${GE_V9}:-Wattribute-alias=2>
|
||||
|
||||
# Broke on MethodBind templates before GCC 11.
|
||||
$<${GT_V11}:-Wlogical-op>
|
||||
|
||||
# Regression in GCC 9/10, spams so much in our variadic templates that we need to outright disable it.
|
||||
$<${LT_V11}:-Wno-type-limits>
|
||||
|
||||
# False positives in our error macros, see GH-58747.
|
||||
$<${GE_V12}:-Wno-return-type>
|
||||
>
|
||||
)
|
||||
|
||||
target_compile_definitions(
|
||||
godot-cpp
|
||||
PUBLIC
|
||||
GDEXTENSION
|
||||
|
||||
# features
|
||||
$<${DEBUG_FEATURES}:DEBUG_ENABLED DEBUG_METHODS_ENABLED>
|
||||
|
||||
$<${IS_DEV_BUILD}:DEV_ENABLED>
|
||||
|
||||
$<${HOT_RELOAD}:HOT_RELOAD_ENABLED>
|
||||
|
||||
$<$<STREQUAL:${GODOTCPP_PRECISION},double>:REAL_T_IS_DOUBLE>
|
||||
|
||||
$<${IS_MSVC}:$<${DISABLE_EXCEPTIONS}:_HAS_EXCEPTIONS=0>>
|
||||
|
||||
$<${THREADS_ENABLED}:THREADS_ENABLED>
|
||||
)
|
||||
|
||||
target_link_options(
|
||||
godot-cpp
|
||||
PUBLIC
|
||||
$<${DEBUG_SYMBOLS}:$<${IS_MSVC}:/DEBUG:FULL>>
|
||||
|
||||
$<$<NOT:${DEBUG_SYMBOLS}>:
|
||||
$<${IS_GNU}:-s>
|
||||
$<${IS_CLANG}:-s>
|
||||
$<${IS_APPLECLANG}:-Wl,-S -Wl,-x -Wl,-dead_strip>
|
||||
>
|
||||
PRIVATE
|
||||
$<${IS_MSVC}:
|
||||
/WX # treat link warnings as errors.
|
||||
/MANIFEST:NO # We dont need a manifest
|
||||
>
|
||||
)
|
||||
# gersemi: on
|
||||
endfunction()
|
||||
40
cobor_vm_extension/godot-cpp/cmake/emsdkHack.cmake
Normal file
40
cobor_vm_extension/godot-cpp/cmake/emsdkHack.cmake
Normal file
@@ -0,0 +1,40 @@
|
||||
#[=======================================================================[.rst:
|
||||
emsdkHack
|
||||
---------
|
||||
|
||||
The Emscripten platform doesn't support the use of shared libraries as known by cmake.
|
||||
|
||||
* https://github.com/emscripten-core/emscripten/issues/15276
|
||||
* https://github.com/emscripten-core/emscripten/issues/17804
|
||||
|
||||
This workaround only works due to the way the cmake scripts are loaded.
|
||||
|
||||
Prior to the use of ``project( ... )`` directive we need to set
|
||||
``CMAKE_PROJECT_INCLUDE=cmake/emscripten.cmake``.
|
||||
This file will be loaded after the toolchain overriding the settings that
|
||||
prevent shared library building.
|
||||
|
||||
CMAKE_PROJECT_INCLUDE was Added in version 3.15.
|
||||
``CMAKE_PROJECT_<projectName>_INCLUDE`` was Added in version 3.17:
|
||||
|
||||
More information on cmake's `code injection`_
|
||||
|
||||
.. _code injection:https://cmake.org/cmake/help/latest/command/project.html#code-injection
|
||||
|
||||
Overwrite Shared Library Properties to allow shared libs to be generated.
|
||||
]=======================================================================]
|
||||
if(EMSCRIPTEN)
|
||||
set_property(GLOBAL PROPERTY TARGET_SUPPORTS_SHARED_LIBS TRUE)
|
||||
set(CMAKE_SHARED_LIBRARY_CREATE_C_FLAGS "-sSIDE_MODULE=1")
|
||||
set(CMAKE_SHARED_LIBRARY_CREATE_CXX_FLAGS "-sSIDE_MODULE=1")
|
||||
set(CMAKE_SHARED_LIBRARY_SUFFIX) # remove the suffix from the shared lib
|
||||
set(CMAKE_STRIP FALSE) # used by default in pybind11 on .so modules
|
||||
|
||||
# The Emscripten toolchain sets the default value for EMSCRIPTEN_SYSTEM_PROCESSOR to x86
|
||||
# and copies that to CMAKE_SYSTEM_PROCESSOR. We don't want that.
|
||||
set(CMAKE_SYSTEM_PROCESSOR "wasm32")
|
||||
# the above prevents the need for logic like:
|
||||
#if( ${CMAKE_SYSTEM_NAME} STREQUAL Emscripten )
|
||||
# set( SYSTEM_ARCH wasm32 )
|
||||
#endif ()
|
||||
endif()
|
||||
390
cobor_vm_extension/godot-cpp/cmake/godotcpp.cmake
Normal file
390
cobor_vm_extension/godot-cpp/cmake/godotcpp.cmake
Normal file
@@ -0,0 +1,390 @@
|
||||
#[=======================================================================[.rst:
|
||||
godotcpp.cmake
|
||||
--------------
|
||||
|
||||
As godot-cpp is a C++ project, there are no C files, and detection of a C
|
||||
compiler is unnecessary. When CMake performs the configure process, if a
|
||||
C compiler is specified, like in a toolchain, or from an IDE, then it will
|
||||
print a warning stating that the CMAKE_C_COMPILER compiler is unused.
|
||||
This if statement simply silences that warning.
|
||||
]=======================================================================]
|
||||
if(CMAKE_C_COMPILER)
|
||||
endif()
|
||||
|
||||
#[[ Include Platform Files
|
||||
Because these files are included into the top level CMakeLists.txt before the
|
||||
project directive, it means that
|
||||
|
||||
CMAKE_CURRENT_SOURCE_DIR is the location of godot-cpp's CMakeLists.txt
|
||||
CMAKE_SOURCE_DIR is the location where any prior project() directive was ]]
|
||||
include(${CMAKE_CURRENT_SOURCE_DIR}/cmake/GodotCPPModule.cmake)
|
||||
include(${CMAKE_CURRENT_SOURCE_DIR}/cmake/common_compiler_flags.cmake)
|
||||
include(${CMAKE_CURRENT_SOURCE_DIR}/cmake/android.cmake)
|
||||
include(${CMAKE_CURRENT_SOURCE_DIR}/cmake/ios.cmake)
|
||||
include(${CMAKE_CURRENT_SOURCE_DIR}/cmake/linux.cmake)
|
||||
include(${CMAKE_CURRENT_SOURCE_DIR}/cmake/macos.cmake)
|
||||
include(${CMAKE_CURRENT_SOURCE_DIR}/cmake/web.cmake)
|
||||
include(${CMAKE_CURRENT_SOURCE_DIR}/cmake/windows.cmake)
|
||||
|
||||
# Detect number of processors
|
||||
include(ProcessorCount)
|
||||
ProcessorCount(PROC_MAX)
|
||||
message("Auto-detected ${PROC_MAX} CPU cores available for build parallelism.")
|
||||
|
||||
# List of known platforms
|
||||
set(PLATFORM_LIST
|
||||
linux
|
||||
macos
|
||||
windows
|
||||
android
|
||||
ios
|
||||
web
|
||||
)
|
||||
|
||||
# List of known architectures
|
||||
set(ARCH_LIST
|
||||
x86_32
|
||||
x86_64
|
||||
arm32
|
||||
arm64
|
||||
rv64
|
||||
ppc32
|
||||
ppc64
|
||||
wasm32
|
||||
)
|
||||
|
||||
#[=============================[ godot_arch_name ]=============================]
|
||||
#[[ Function to map CMAKE_SYSTEM_PROCESSOR names to godot arch equivalents ]]
|
||||
function(godot_arch_name OUTVAR)
|
||||
# Special case for macos universal builds that target both x86_64 and arm64
|
||||
if(DEFINED CMAKE_OSX_ARCHITECTURES)
|
||||
if("x86_64" IN_LIST CMAKE_OSX_ARCHITECTURES AND "arm64" IN_LIST CMAKE_OSX_ARCHITECTURES)
|
||||
set(${OUTVAR} "universal" PARENT_SCOPE)
|
||||
return()
|
||||
endif()
|
||||
endif()
|
||||
|
||||
# Direct match early out.
|
||||
string(TOLOWER "${CMAKE_SYSTEM_PROCESSOR}" ARCH)
|
||||
if(ARCH IN_LIST ARCH_LIST)
|
||||
set(${OUTVAR} "${ARCH}" PARENT_SCOPE)
|
||||
return()
|
||||
endif()
|
||||
|
||||
# Known aliases
|
||||
set(x86_64 "w64;amd64;x86-64")
|
||||
set(arm32 "armv7;armv7-a")
|
||||
set(arm64 "armv8;arm64v8;aarch64;armv8-a")
|
||||
set(rv64 "rv;riscv;riscv64")
|
||||
set(ppc32 "ppcle;ppc")
|
||||
set(ppc64 "ppc64le")
|
||||
|
||||
if(ARCH IN_LIST x86_64)
|
||||
set(${OUTVAR} "x86_64" PARENT_SCOPE)
|
||||
elseif(ARCH IN_LIST arm32)
|
||||
set(${OUTVAR} "arm32" PARENT_SCOPE)
|
||||
elseif(ARCH IN_LIST arm64)
|
||||
set(${OUTVAR} "arm64" PARENT_SCOPE)
|
||||
elseif(ARCH IN_LIST rv64)
|
||||
set(${OUTVAR} "rv64" PARENT_SCOPE)
|
||||
elseif(ARCH IN_LIST ppc32)
|
||||
set(${OUTVAR} "ppc32" PARENT_SCOPE)
|
||||
elseif(ARCH IN_LIST ppc64)
|
||||
set(${OUTVAR} "ppc64" PARENT_SCOPE)
|
||||
elseif(ARCH MATCHES "86")
|
||||
# Catches x86, i386, i486, i586, i686, etc.
|
||||
set(${OUTVAR} "x86_32" PARENT_SCOPE)
|
||||
else()
|
||||
# Default value is whatever the processor is.
|
||||
set(${OUTVAR} ${CMAKE_SYSTEM_PROCESSOR} PARENT_SCOPE)
|
||||
endif()
|
||||
endfunction()
|
||||
|
||||
# Function to define all the options.
|
||||
function(godotcpp_options)
|
||||
#NOTE: platform is managed using toolchain files.
|
||||
#NOTE: arch is managed by using toolchain files.
|
||||
# To create a universal build for macos, set CMAKE_OSX_ARCHITECTURES
|
||||
|
||||
set(GODOTCPP_TARGET
|
||||
"template_debug"
|
||||
CACHE STRING
|
||||
"Which target to generate. valid values are: template_debug, template_release, and editor"
|
||||
)
|
||||
set_property(CACHE GODOTCPP_TARGET PROPERTY STRINGS "template_debug;template_release;editor")
|
||||
|
||||
# Input from user for GDExtension interface header and the API JSON file
|
||||
set(GODOTCPP_GDEXTENSION_DIR
|
||||
"gdextension"
|
||||
CACHE PATH
|
||||
"Path to a custom directory containing GDExtension interface header and API JSON file ( /path/to/gdextension_dir )"
|
||||
)
|
||||
set(GODOTCPP_CUSTOM_API_FILE
|
||||
""
|
||||
CACHE FILEPATH
|
||||
"Path to a custom GDExtension API JSON file (takes precedence over `GODOTCPP_GDEXTENSION_DIR`) ( /path/to/custom_api_file )"
|
||||
)
|
||||
|
||||
#TODO generate_bindings
|
||||
|
||||
option(GODOTCPP_GENERATE_TEMPLATE_GET_NODE "Generate a template version of the Node class's get_node. (ON|OFF)" ON)
|
||||
|
||||
#TODO build_library
|
||||
|
||||
set(GODOTCPP_PRECISION "single" CACHE STRING "Set the floating-point precision level (single|double)")
|
||||
|
||||
set(GODOTCPP_THREADS ON CACHE BOOL "Enable threading support")
|
||||
|
||||
#TODO compiledb
|
||||
#TODO compiledb_file
|
||||
|
||||
set(GODOTCPP_BUILD_PROFILE "" CACHE PATH "Path to a file containing a feature build profile")
|
||||
|
||||
set(GODOTCPP_USE_HOT_RELOAD "" CACHE BOOL "Enable the extra accounting required to support hot reload. (ON|OFF)")
|
||||
|
||||
# Disable exception handling. Godot doesn't use exceptions anywhere, and this
|
||||
# saves around 20% of binary size and very significant build time (GH-80513).
|
||||
option(GODOTCPP_DISABLE_EXCEPTIONS "Force disabling exception handling code (ON|OFF)" ON)
|
||||
|
||||
set(GODOTCPP_SYMBOL_VISIBILITY
|
||||
"hidden"
|
||||
CACHE STRING
|
||||
"Symbols visibility on GNU platforms. Use 'auto' to apply the default value. (auto|visible|hidden)"
|
||||
)
|
||||
set_property(CACHE GODOTCPP_SYMBOL_VISIBILITY PROPERTY STRINGS "auto;visible;hidden")
|
||||
|
||||
#TODO optimize
|
||||
|
||||
option(GODOTCPP_DEV_BUILD "Developer build with dev-only debugging code (DEV_ENABLED)" OFF)
|
||||
|
||||
#[[ debug_symbols
|
||||
Debug symbols are enabled by using the Debug or RelWithDebInfo build configurations.
|
||||
Single Config Generator is set at configure time
|
||||
|
||||
cmake ../ -DCMAKE_BUILD_TYPE=Debug
|
||||
|
||||
Multi-Config Generator is set at build time
|
||||
|
||||
cmake --build . --config Debug
|
||||
|
||||
]]
|
||||
|
||||
# FIXME These options are not present in SCons, and perhaps should be added there.
|
||||
option(GODOTCPP_SYSTEM_HEADERS "Expose headers as SYSTEM." OFF)
|
||||
option(GODOTCPP_WARNING_AS_ERROR "Treat warnings as errors" OFF)
|
||||
|
||||
# Enable Testing
|
||||
option(GODOTCPP_ENABLE_TESTING "Enable the godot-cpp.test.<target> integration testing targets" OFF)
|
||||
|
||||
#[[ Target Platform Options ]]
|
||||
android_options()
|
||||
ios_options()
|
||||
linux_options()
|
||||
macos_options()
|
||||
web_options()
|
||||
windows_options()
|
||||
endfunction()
|
||||
|
||||
#[===========================[ Target Generation ]===========================]
|
||||
function(godotcpp_generate)
|
||||
#[[ Multi-Threaded MSVC Compilation
|
||||
When using the MSVC compiler the build command -j <n> only specifies
|
||||
parallel jobs or targets, and not multi-threaded compilation To speed up
|
||||
compile times on msvc, the /MP <n> flag can be set. But we need to set it
|
||||
at configure time.
|
||||
|
||||
MSVC is true when the compiler is some version of Microsoft Visual C++ or
|
||||
another compiler simulating the Visual C++ cl command-line syntax. ]]
|
||||
if(MSVC)
|
||||
math(EXPR PROC_N "(${PROC_MAX}-1) | (${X}-2)>>31 & 1")
|
||||
message("Using ${PROC_N} cores for multi-threaded compilation.")
|
||||
# TODO You can override it at configure time with ...." )
|
||||
else()
|
||||
message(
|
||||
"Using ${CMAKE_BUILD_PARALLEL_LEVEL} cores, You can override"
|
||||
" it at configure time by using -j <n> or --parallel <n> on the build"
|
||||
" command."
|
||||
)
|
||||
message(" eg. cmake --build . -j 7 ...")
|
||||
endif()
|
||||
|
||||
#[[ GODOTCPP_SYMBOL_VISIBLITY
|
||||
To match the SCons options, the allowed values are "auto", "visible", and "hidden"
|
||||
This effects the compiler flag_ -fvisibility=[default|internal|hidden|protected]
|
||||
The corresponding target option CXX_VISIBILITY_PRESET accepts the compiler values.
|
||||
|
||||
TODO: It is probably worth a pull request which changes both to use the compiler values
|
||||
.. _flag:https://gcc.gnu.org/onlinedocs/gcc/Code-Gen-Options.html#index-fvisibility
|
||||
]]
|
||||
if(${GODOTCPP_SYMBOL_VISIBILITY} STREQUAL "auto" OR ${GODOTCPP_SYMBOL_VISIBILITY} STREQUAL "visible")
|
||||
set(GODOTCPP_SYMBOL_VISIBILITY "default")
|
||||
endif()
|
||||
|
||||
# Setup variable to optionally mark headers as SYSTEM
|
||||
set(GODOTCPP_SYSTEM_HEADERS_ATTRIBUTE "")
|
||||
if(GODOTCPP_SYSTEM_HEADERS)
|
||||
set(GODOTCPP_SYSTEM_HEADERS_ATTRIBUTE SYSTEM)
|
||||
endif()
|
||||
|
||||
#[[ Configure Binding Variables ]]
|
||||
# Generate Binding Parameters (True|False)
|
||||
set(USE_TEMPLATE_GET_NODE "False")
|
||||
if(GODOTCPP_GENERATE_TEMPLATE_GET_NODE)
|
||||
set(USE_TEMPLATE_GET_NODE "True")
|
||||
endif()
|
||||
|
||||
# Bits (32|64)
|
||||
math(EXPR BITS "${CMAKE_SIZEOF_VOID_P} * 8") # CMAKE_SIZEOF_VOID_P refers to target architecture.
|
||||
|
||||
# API json File
|
||||
set(GODOTCPP_GDEXTENSION_API_FILE "${GODOTCPP_GDEXTENSION_DIR}/extension_api.json")
|
||||
if(GODOTCPP_CUSTOM_API_FILE) # User-defined override.
|
||||
set(GODOTCPP_GDEXTENSION_API_FILE "${GODOTCPP_CUSTOM_API_FILE}")
|
||||
endif()
|
||||
|
||||
# Build Profile
|
||||
if(GODOTCPP_BUILD_PROFILE)
|
||||
message(STATUS "Using build profile to trim api file")
|
||||
message("\tBUILD_PROFILE = '${GODOTCPP_BUILD_PROFILE}'")
|
||||
message("\tAPI_SOURCE = '${GODOTCPP_GDEXTENSION_API_FILE}'")
|
||||
build_profile_generate_trimmed_api(
|
||||
"${GODOTCPP_BUILD_PROFILE}"
|
||||
"${GODOTCPP_GDEXTENSION_API_FILE}"
|
||||
"${CMAKE_CURRENT_BINARY_DIR}/extension_api.json"
|
||||
)
|
||||
set(GODOTCPP_GDEXTENSION_API_FILE "${CMAKE_CURRENT_BINARY_DIR}/extension_api.json")
|
||||
endif()
|
||||
|
||||
message(STATUS "GODOTCPP_GDEXTENSION_API_FILE = '${GODOTCPP_GDEXTENSION_API_FILE}'")
|
||||
|
||||
# generate the file list to use
|
||||
binding_generator_get_file_list( GENERATED_FILES_LIST
|
||||
"${GODOTCPP_GDEXTENSION_API_FILE}"
|
||||
"${CMAKE_CURRENT_BINARY_DIR}"
|
||||
)
|
||||
|
||||
binding_generator_generate_bindings(
|
||||
"${GODOTCPP_GDEXTENSION_API_FILE}"
|
||||
"${USE_TEMPLATE_GET_NODE}"
|
||||
"${BITS}"
|
||||
"${GODOTCPP_PRECISION}"
|
||||
"${CMAKE_CURRENT_BINARY_DIR}"
|
||||
)
|
||||
|
||||
### Platform is derived from the toolchain target
|
||||
# See GeneratorExpressions PLATFORM_ID and CMAKE_SYSTEM_NAME
|
||||
string(
|
||||
CONCAT
|
||||
SYSTEM_NAME
|
||||
"$<$<PLATFORM_ID:Android>:android.${ANDROID_ABI}>"
|
||||
"$<$<PLATFORM_ID:iOS>:ios>"
|
||||
"$<$<PLATFORM_ID:Linux>:linux>"
|
||||
"$<$<PLATFORM_ID:Darwin>:macos>"
|
||||
"$<$<PLATFORM_ID:Emscripten>:web>"
|
||||
"$<$<PLATFORM_ID:Windows>:windows>"
|
||||
"$<$<PLATFORM_ID:Msys>:windows>"
|
||||
)
|
||||
|
||||
# Process CPU architecture argument.
|
||||
godot_arch_name( ARCH_NAME )
|
||||
|
||||
# Transform options into generator expressions
|
||||
set(HOT_RELOAD-UNSET "$<STREQUAL:${GODOTCPP_USE_HOT_RELOAD},>")
|
||||
|
||||
set(DISABLE_EXCEPTIONS "$<BOOL:${GODOTCPP_DISABLE_EXCEPTIONS}>")
|
||||
|
||||
set(THREADS_ENABLED "$<BOOL:${GODOTCPP_THREADS}>")
|
||||
|
||||
# GODOTCPP_DEV_BUILD
|
||||
set(RELEASE_TYPES "Release;MinSizeRel")
|
||||
get_property(IS_MULTI_CONFIG GLOBAL PROPERTY GENERATOR_IS_MULTI_CONFIG)
|
||||
if(IS_MULTI_CONFIG)
|
||||
message(NOTICE "=> Default build type is Debug. For other build types add --config <type> to build command")
|
||||
elseif(GODOTCPP_DEV_BUILD AND CMAKE_BUILD_TYPE IN_LIST RELEASE_TYPES)
|
||||
message(
|
||||
WARNING
|
||||
"=> GODOTCPP_DEV_BUILD implies a Debug-like build but CMAKE_BUILD_TYPE is '${CMAKE_BUILD_TYPE}'"
|
||||
)
|
||||
endif()
|
||||
set(IS_DEV_BUILD "$<BOOL:${GODOTCPP_DEV_BUILD}>")
|
||||
|
||||
### Define our godot-cpp library targets
|
||||
# Generator Expressions that rely on the target
|
||||
set(DEBUG_FEATURES "$<NOT:$<STREQUAL:${GODOTCPP_TARGET},template_release>>")
|
||||
set(HOT_RELOAD "$<IF:${HOT_RELOAD-UNSET},${DEBUG_FEATURES},$<BOOL:${GODOTCPP_USE_HOT_RELOAD}>>")
|
||||
|
||||
# Suffix
|
||||
string(
|
||||
CONCAT
|
||||
GODOTCPP_SUFFIX
|
||||
"$<1:.${SYSTEM_NAME}>"
|
||||
"$<1:.${GODOTCPP_TARGET}>"
|
||||
"$<${IS_DEV_BUILD}:.dev>"
|
||||
"$<$<STREQUAL:${GODOTCPP_PRECISION},double>:.double>"
|
||||
"$<1:.${ARCH_NAME}>"
|
||||
# TODO IOS_SIMULATOR
|
||||
"$<$<NOT:${THREADS_ENABLED}>:.nothreads>"
|
||||
)
|
||||
|
||||
# the godot-cpp.* library targets
|
||||
add_library(godot-cpp STATIC)
|
||||
|
||||
# Without adding this dependency to the binding generator, XCode will complain.
|
||||
add_dependencies(godot-cpp generate_bindings)
|
||||
|
||||
# Added for backwards compatibility with prior cmake solution so that builds dont immediately break
|
||||
# from a missing target.
|
||||
add_library(godot::cpp ALIAS godot-cpp)
|
||||
|
||||
file(GLOB_RECURSE GODOTCPP_SOURCES LIST_DIRECTORIES NO CONFIGURE_DEPENDS src/*.cpp)
|
||||
|
||||
target_sources(godot-cpp PRIVATE ${GODOTCPP_SOURCES} ${GENERATED_FILES_LIST})
|
||||
|
||||
target_include_directories(
|
||||
godot-cpp
|
||||
${GODOTCPP_SYSTEM_HEADERS_ATTRIBUTE}
|
||||
PUBLIC include ${CMAKE_CURRENT_BINARY_DIR}/gen/include ${GODOTCPP_GDEXTENSION_DIR}
|
||||
)
|
||||
|
||||
# gersemi: off
|
||||
set_target_properties(
|
||||
godot-cpp
|
||||
PROPERTIES
|
||||
CXX_STANDARD 17
|
||||
CXX_EXTENSIONS OFF
|
||||
CXX_VISIBILITY_PRESET ${GODOTCPP_SYMBOL_VISIBILITY}
|
||||
|
||||
COMPILE_WARNING_AS_ERROR ${GODOTCPP_WARNING_AS_ERROR}
|
||||
POSITION_INDEPENDENT_CODE ON
|
||||
BUILD_RPATH_USE_ORIGIN ON
|
||||
|
||||
PREFIX "lib"
|
||||
OUTPUT_NAME "${PROJECT_NAME}${GODOTCPP_SUFFIX}"
|
||||
|
||||
ARCHIVE_OUTPUT_DIRECTORY "$<1:${CMAKE_BINARY_DIR}/bin>"
|
||||
|
||||
# Things that are handy to know for dependent targets
|
||||
GODOTCPP_PLATFORM "${SYSTEM_NAME}"
|
||||
GODOTCPP_TARGET "${GODOTCPP_TARGET}"
|
||||
GODOTCPP_ARCH "${ARCH_NAME}"
|
||||
GODOTCPP_PRECISION "${GODOTCPP_PRECISION}"
|
||||
GODOTCPP_SUFFIX "${GODOTCPP_SUFFIX}"
|
||||
|
||||
# Some IDE's respect this property to logically group targets
|
||||
FOLDER "godot-cpp"
|
||||
)
|
||||
# gersemi: on
|
||||
if(CMAKE_SYSTEM_NAME STREQUAL Android)
|
||||
android_generate()
|
||||
elseif(CMAKE_SYSTEM_NAME STREQUAL iOS)
|
||||
ios_generate()
|
||||
elseif(CMAKE_SYSTEM_NAME STREQUAL Linux)
|
||||
linux_generate()
|
||||
elseif(CMAKE_SYSTEM_NAME STREQUAL Darwin)
|
||||
macos_generate()
|
||||
elseif(CMAKE_SYSTEM_NAME STREQUAL Emscripten)
|
||||
web_generate()
|
||||
elseif(CMAKE_SYSTEM_NAME STREQUAL Windows)
|
||||
windows_generate()
|
||||
endif()
|
||||
endfunction()
|
||||
36
cobor_vm_extension/godot-cpp/cmake/ios.cmake
Normal file
36
cobor_vm_extension/godot-cpp/cmake/ios.cmake
Normal file
@@ -0,0 +1,36 @@
|
||||
#[=======================================================================[.rst:
|
||||
iOS
|
||||
---
|
||||
|
||||
This file contains functions for options and configuration for targeting the
|
||||
iOS platform
|
||||
|
||||
]=======================================================================]
|
||||
|
||||
#[==============================[ iOS Options ]==============================]
|
||||
function(ios_options)
|
||||
#[[ Options from SCons
|
||||
|
||||
TODO ios_simulator: Target iOS Simulator
|
||||
Default: False
|
||||
|
||||
TODO ios_min_version: Target minimum iphoneos/iphonesimulator version
|
||||
Default: 12.0
|
||||
|
||||
TODO IOS_TOOLCHAIN_PATH: Path to iOS toolchain
|
||||
Default: "/Applications/Xcode.app/Contents/Developer/Toolchains/XcodeDefault.xctoolchain",
|
||||
|
||||
TODO IOS_SDK_PATH: Path to the iOS SDK
|
||||
Default: ''
|
||||
|
||||
TODO ios_triple: Triple for ios toolchain
|
||||
Default: if has_ios_osxcross(): 'ios_triple' else ''
|
||||
]]
|
||||
endfunction()
|
||||
|
||||
#[===========================[ Target Generation ]===========================]
|
||||
function(ios_generate)
|
||||
target_compile_definitions(godot-cpp PUBLIC IOS_ENABLED UNIX_ENABLED)
|
||||
|
||||
common_compiler_flags()
|
||||
endfunction()
|
||||
24
cobor_vm_extension/godot-cpp/cmake/linux.cmake
Normal file
24
cobor_vm_extension/godot-cpp/cmake/linux.cmake
Normal file
@@ -0,0 +1,24 @@
|
||||
#[=======================================================================[.rst:
|
||||
Linux
|
||||
-----
|
||||
|
||||
This file contains functions for options and configuration for targeting the
|
||||
Linux platform
|
||||
|
||||
]=======================================================================]
|
||||
|
||||
#[=============================[ Linux Options ]=============================]
|
||||
function(linux_options)
|
||||
#[[ Options from SCons
|
||||
use_llvm : Use the LLVM compiler
|
||||
Not implemented as compiler selection is managed by CMake. Look to
|
||||
doc/cmake.rst for examples.
|
||||
]]
|
||||
endfunction()
|
||||
|
||||
#[===========================[ Target Generation ]===========================]
|
||||
function(linux_generate)
|
||||
target_compile_definitions(godot-cpp PUBLIC LINUX_ENABLED UNIX_ENABLED)
|
||||
|
||||
common_compiler_flags()
|
||||
endfunction()
|
||||
53
cobor_vm_extension/godot-cpp/cmake/macos.cmake
Normal file
53
cobor_vm_extension/godot-cpp/cmake/macos.cmake
Normal file
@@ -0,0 +1,53 @@
|
||||
#[=======================================================================[.rst:
|
||||
MacOS
|
||||
-----
|
||||
|
||||
This file contains functions for options and configuration for targeting the
|
||||
MacOS platform
|
||||
|
||||
Universal Builds
|
||||
----------------
|
||||
|
||||
To build universal binaries, ie targeting both x86_64 and arm64, use
|
||||
the CMAKE_OSX_ARCHITECTURES variable prior to any project calls.
|
||||
https://cmake.org/cmake/help/latest/variable/CMAKE_OSX_ARCHITECTURES.html
|
||||
|
||||
]=======================================================================]
|
||||
|
||||
# Find Requirements
|
||||
if(APPLE)
|
||||
set(CMAKE_OSX_SYSROOT $ENV{SDKROOT})
|
||||
find_library(
|
||||
COCOA_LIBRARY
|
||||
REQUIRED
|
||||
NAMES Cocoa
|
||||
PATHS ${CMAKE_OSX_SYSROOT}/System/Library
|
||||
PATH_SUFFIXES Frameworks
|
||||
NO_DEFAULT_PATH
|
||||
)
|
||||
endif(APPLE)
|
||||
|
||||
#[=============================[ MacOS Options ]=============================]
|
||||
function(macos_options)
|
||||
#[[ Options from SCons
|
||||
TODO macos_deployment_target: macOS deployment target
|
||||
Default: 'default'
|
||||
|
||||
TODO macos_sdk_path: macOS SDK path
|
||||
Default: ''
|
||||
|
||||
TODO osxcross_sdk: OSXCross SDK version
|
||||
Default: if has_osxcross(): "darwin16" else None
|
||||
]]
|
||||
endfunction()
|
||||
|
||||
#[===========================[ Target Generation ]===========================]
|
||||
function(macos_generate)
|
||||
target_compile_definitions(godot-cpp PUBLIC MACOS_ENABLED UNIX_ENABLED)
|
||||
|
||||
target_link_options(godot-cpp PUBLIC -Wl,-undefined,dynamic_lookup)
|
||||
|
||||
target_link_libraries(godot-cpp INTERFACE ${COCOA_LIBRARY})
|
||||
|
||||
common_compiler_flags()
|
||||
endfunction()
|
||||
39
cobor_vm_extension/godot-cpp/cmake/web.cmake
Normal file
39
cobor_vm_extension/godot-cpp/cmake/web.cmake
Normal file
@@ -0,0 +1,39 @@
|
||||
#[=======================================================================[.rst:
|
||||
Web
|
||||
---
|
||||
|
||||
This file contains functions for options and configuration for targeting the
|
||||
Web platform
|
||||
|
||||
]=======================================================================]
|
||||
|
||||
# Emscripten requires this hack for use of the SHARED option
|
||||
set(CMAKE_PROJECT_godot-cpp_INCLUDE cmake/emsdkHack.cmake)
|
||||
|
||||
#[==============================[ Web Options ]==============================]
|
||||
function(web_options)
|
||||
endfunction()
|
||||
|
||||
#[===========================[ Target Generation ]===========================]
|
||||
function(web_generate)
|
||||
target_compile_definitions(godot-cpp PUBLIC WEB_ENABLED UNIX_ENABLED)
|
||||
|
||||
target_compile_options(
|
||||
godot-cpp
|
||||
PUBLIC #
|
||||
-sSIDE_MODULE
|
||||
-sSUPPORT_LONGJMP=wasm
|
||||
$<${THREADS_ENABLED}:-sUSE_PTHREADS=1>
|
||||
)
|
||||
|
||||
target_link_options(
|
||||
godot-cpp
|
||||
INTERFACE #
|
||||
-sWASM_BIGINT
|
||||
-sSUPPORT_LONGJMP=wasm
|
||||
-fvisibility=hidden
|
||||
-shared
|
||||
)
|
||||
|
||||
common_compiler_flags()
|
||||
endfunction()
|
||||
116
cobor_vm_extension/godot-cpp/cmake/windows.cmake
Normal file
116
cobor_vm_extension/godot-cpp/cmake/windows.cmake
Normal file
@@ -0,0 +1,116 @@
|
||||
#[=======================================================================[.rst:
|
||||
Windows
|
||||
-------
|
||||
This file contains functions for options and configuration for targeting the
|
||||
Windows platform
|
||||
|
||||
Because this file is included into the top level CMakelists.txt before the
|
||||
project directive, it means that
|
||||
|
||||
* ``CMAKE_CURRENT_SOURCE_DIR`` is the location of godot-cpp's CMakeLists.txt
|
||||
* ``CMAKE_SOURCE_DIR`` is the location where any prior ``project(...)``
|
||||
directive was
|
||||
|
||||
MSVC Runtime Selection
|
||||
----------------------
|
||||
|
||||
There are two main ways to set the msvc runtime library;
|
||||
Using ``target_compile_options()`` to add the flags
|
||||
or using the ``CMAKE_MSVC_RUNTIME_LIBRARY`` property_ abstraction, introduced
|
||||
in CMake version 3.15 with the policy CMP0091_ to remove the flags from
|
||||
``CMAKE_<LANG>_FLAGS_<CONFIG>``.
|
||||
|
||||
Default: ``CMAKE_MSVC_RUNTIME_LIBRARY="MultiThreaded$<$<CONFIG:Debug>:Debug>DLL"``
|
||||
|
||||
This initializes each target's ``MSVC_RUNTIME_LIBRARY`` property at the time of
|
||||
target creation.
|
||||
|
||||
it is stated in the msvc_ documentation that: "All modules passed to a given
|
||||
invocation of the linker must have been compiled with the same runtime library
|
||||
compiler option (/MD, /MT, /LD)."
|
||||
|
||||
This creates a conundrum for us, the ``CMAKE_MSVC_RUNTIME_LIBRARY`` needs to be
|
||||
correct at the time the target is created, but we have no control over the
|
||||
consumers CMake scripts, and the per-target ``MSVC_RUNTIME_LIBRARY`` property
|
||||
is not transient.
|
||||
|
||||
It has been raised that not using ``CMAKE_MSVC_RUNTIME_LIBRARY`` can also cause
|
||||
issues_ when a dependency( independent to godot-cpp ) that doesn't set any
|
||||
runtime flags, which relies purely on the ``CMAKE_MSVC_RUNTIME_LIBRARY``
|
||||
variable will very likely not have the correct msvc runtime flags set.
|
||||
|
||||
So we'll set ``CMAKE_MSVC_RUNTIME_LIBRARY`` as CACHE STRING so that it will be
|
||||
available for consumer target definitions, but also be able to be overridden if
|
||||
needed.
|
||||
|
||||
Additionally we message consumers notifying them and pointing to this
|
||||
documentation.
|
||||
|
||||
.. _CMP0091:https://cmake.org/cmake/help/latest/policy/CMP0091.html
|
||||
.. _property:https://cmake.org/cmake/help/latest/variable/CMAKE_MSVC_RUNTIME_LIBRARY.html
|
||||
.. https://discourse.cmake.org/t/mt-staticrelease-doesnt-match-value-md-dynamicrelease/5428/4
|
||||
.. _msvc: https://learn.microsoft.com/en-us/cpp/build/reference/md-mt-ld-use-run-time-library
|
||||
.. _issues: https://github.com/godotengine/godot-cpp/issues/1699
|
||||
|
||||
]=======================================================================]
|
||||
|
||||
#[============================[ Windows Options ]============================]
|
||||
function(windows_options)
|
||||
#[[ Options from SCons
|
||||
|
||||
TODO silence_msvc: Silence MSVC's cl/link stdout bloat, redirecting errors to stderr
|
||||
Default: True
|
||||
|
||||
These three options will not implemented as compiler selection is managed
|
||||
by CMake toolchain files. Look to doc/cmake.rst for examples.
|
||||
use_mingw: Use the MinGW compiler instead of MSVC - only effective on Windows
|
||||
use_llvm: Use the LLVM compiler (MVSC or MinGW depending on the use_mingw flag
|
||||
mingw_prefix: MinGW prefix
|
||||
]]
|
||||
|
||||
option(GODOTCPP_USE_STATIC_CPP "Link MinGW/MSVC C++ runtime libraries statically" ON)
|
||||
option(GODOTCPP_DEBUG_CRT "Compile with MSVC's debug CRT (/MDd)" OFF)
|
||||
|
||||
message(
|
||||
STATUS
|
||||
"If not already cached, setting CMAKE_MSVC_RUNTIME_LIBRARY.\n"
|
||||
"\tFor more information please read godot-cpp/cmake/windows.cmake"
|
||||
)
|
||||
|
||||
set(CMAKE_MSVC_RUNTIME_LIBRARY
|
||||
"MultiThreaded$<IF:$<BOOL:${GODOTCPP_DEBUG_CRT}>,DebugDLL,$<$<NOT:$<BOOL:${GODOTCPP_USE_STATIC_CPP}>>:DLL>>"
|
||||
CACHE STRING
|
||||
"Select the MSVC runtime library for use by compilers targeting the MSVC ABI."
|
||||
)
|
||||
endfunction()
|
||||
|
||||
#[===========================[ Target Generation ]===========================]
|
||||
function(windows_generate)
|
||||
set(STATIC_CPP "$<BOOL:${GODOTCPP_USE_STATIC_CPP}>")
|
||||
|
||||
set_target_properties(godot-cpp PROPERTIES PDB_OUTPUT_DIRECTORY "$<1:${CMAKE_SOURCE_DIR}/bin>")
|
||||
|
||||
target_compile_definitions(
|
||||
godot-cpp
|
||||
PUBLIC WINDOWS_ENABLED $<${IS_MSVC}: TYPED_METHOD_BIND NOMINMAX >
|
||||
)
|
||||
|
||||
# gersemi: off
|
||||
target_link_options(
|
||||
godot-cpp
|
||||
PUBLIC
|
||||
$<${NOT_MSVC}:
|
||||
-Wl,--no-undefined
|
||||
$<${STATIC_CPP}:
|
||||
-static
|
||||
-static-libgcc
|
||||
-static-libstdc++
|
||||
>
|
||||
>
|
||||
|
||||
$<${IS_CLANG}:-lstdc++>
|
||||
)
|
||||
# gersemi: on
|
||||
|
||||
common_compiler_flags()
|
||||
endfunction()
|
||||
Reference in New Issue
Block a user